Gecko [ nbspublicschool.com ]

Name	Size	Permission
_bootctl	721 B	-rw-r--r--
_coredumpctl	1.47 KB	-rw-r--r--
_hostnamectl	2.17 KB	-rw-r--r--
_journalctl	4.56 KB	-rw-r--r--
_kernel-install	614 B	-rw-r--r--
_localectl	3.46 KB	-rw-r--r--
_loginctl	4.04 KB	-rw-r--r--
_machinectl	1.67 KB	-rw-r--r--
_sd_hosts_or_user_at_host	79 B	-rw-r--r--
_sd_machines	318 B	-rw-r--r--
_sd_outputmodes	202 B	-rw-r--r--
_sd_unit_files	235 B	-rw-r--r--
_systemctl	14.63 KB	-rw-r--r--
_systemd	3.69 KB	-rw-r--r--
_systemd-analyze	2.33 KB	-rw-r--r--
_systemd-delta	527 B	-rw-r--r--
_systemd-inhibit	958 B	-rw-r--r--
_systemd-nspawn	3.57 KB	-rw-r--r--
_systemd-run	1.97 KB	-rw-r--r--
_systemd-tmpfiles	699 B	-rw-r--r--
_timedatectl	1.96 KB	-rw-r--r--
_udevadm	5.81 KB	-rw-r--r--

Code Editor : _timedatectl

#compdef timedatectl

_timedatectl_set-timezone(){
    local -a _timezones
    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
    compadd "$_timezones[@]"
}

_timedatectl_set-time(){
    _message "YYYY-MM-DD HH:MM:SS"
}

_timedatectl_set-local-rtc(){
    local -a _options
    _options=(
        '0:Maintain RTC in universal time'
        '1:Maintain RTC in local time'
    )
    _describe options _options
}

_timedatectl_set-ntp(){
    local -a _options
    _options=(
        '0:Disable NTP based network time configuration'
        '1:Enable NTP based network time configuration'
    )
    _describe options _options
}

_timedatectl_command(){
    local -a _timedatectl_cmds
    _timedatectl_cmds=(
        'status:Show current time settings'
        'set-time:Set system time'
        'set-timezone:Set system timezone'
        'list-timezones:Show known timezones'
        'set-local-rtc:Control whether RTC is in local time'
        'set-ntp:Control whether NTP is enabled'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'timedatectl command' _timedatectl_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd )); then
            if (( $+functions[_timedatectl_$cmd] )); then
                _timedatectl_$cmd
            else
                _message "no more options"
            fi
        else
            _message "unknown timedatectl command: $words[1]"
        fi
    fi
}

_arguments -s \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-ask-password[Do not prompt for password]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
    '*::timedatectl commands:_timedatectl_command'

${this.title}

Code Editor : _timedatectl